Arduino - Teclado numérico - Servomotor
En este tutorial, vamos a aprender cómo usar un teclado numérico, un servomotor y Arduino juntos:
- Si un usuario introduce una contraseña autorizada en el teclado numérico, Arduino gira el servomotor a 90°.
- Después de un período de tiempo, Arduino devuelve el servomotor a 0° sin usar la función delay().
- El código de Arduino también admite varias contraseñas.
Hardware Requerido
Or you can buy the following kits:
| 1 | × | DIYables STEM V3 Starter Kit (Arduino included) | |
| 1 | × | DIYables Sensor Kit (30 sensors/displays) | |
| 1 | × | DIYables Sensor Kit (18 sensors/displays) |
Divulgación: Algunos de los enlaces proporcionados en esta sección son enlaces de afiliado de Amazon. Podemos recibir una comisión por las compras realizadas a través de estos enlaces sin costo adicional para usted. Apreciamos su apoyo.
Acerca del teclado numérico y del servomotor
Si no conoces el teclado numérico y el servomotor (disposición de pines, cómo funciona, cómo programarlo ...), aprende sobre ellos en los siguientes tutoriales:
- Arduino - Keypad tutorial
- Arduino - Servo Motor tutorial
Diagrama de Cableado
This image is created using Fritzing. Click to enlarge image
Código de Arduino: gira el servomotor si la contraseña es correcta
El siguiente código hace que el servomotor se mueva a 90° durante 5 segundos si la contraseña es correcta. Después de 5 segundos, mueve el servomotor a 0°.
/*
* Este código de Arduino fue desarrollado por es.newbiely.com
* Este código de Arduino se proporciona al público sin ninguna restricción.
* Para tutoriales completos y diagramas de cableado, visite:
* https://es.newbiely.com/tutorials/arduino/arduino-keypad-servo-motor
*/
#include <Keypad.h>
#include <Servo.h>
#define ROW_NUM 4 // four rows
#define COLUMN_NUM 4 // four columns
#define SERVO_PIN A0 // // the Arduino pin, which connects to the servo motor
Servo servo; // servo motor
char keys[ROW_NUM][COLUMN_NUM] = {
{'1', '2', '3', 'A'},
{'4', '5', '6', 'B'},
{'7', '8', '9', 'C'},
{'*', '0', '#', 'D'}
};
byte pin_rows[ROW_NUM] = {9, 8, 7, 6}; //connect to the row pinouts of the keypad
byte pin_column[COLUMN_NUM] = {5, 4, 3, 2}; //connect to the column pinouts of the keypad
Keypad keypad = Keypad( makeKeymap(keys), pin_rows, pin_column, ROW_NUM, COLUMN_NUM );
const String password_1 = "ABC1234"; // change your password here
const String password_2 = "5642B"; // change your password here
const String password_3 = "9765"; // change your password here
String input_password;
int angle = 0; // the current angle of servo motor
unsigned long lastTime;
void setup() {
Serial.begin(9600);
input_password.reserve(32); // maximum password size is 32, change if needed
servo.attach(SERVO_PIN);
servo.write(0); // rotate servo motor to 0°
lastTime = millis();
}
void loop() {
char key = keypad.getKey();
if (key) {
Serial.println(key);
if (key == '*') {
input_password = ""; // reset the input password
} else if (key == '#') {
if (input_password == password_1 || input_password == password_2 || input_password == password_3) {
Serial.println("The password is correct, rotating Servo Motor to 90°");
angle = 90;
servo.write(angle);
lastTime = millis();
} else {
Serial.println("The password is incorrect, try again");
}
input_password = ""; // reset the input password
} else {
input_password += key; // append new character to input password string
}
}
if (angle == 90 && (millis() - lastTime) > 5000) { // 5 seconds
angle = 0;
servo.write(angle);
Serial.println("Rotating Servo Motor to 0°");
}
}
Pasos R\u00e1pidos
- Conecta Arduino a la PC mediante un cable USB
- Abre Arduino IDE, selecciona la placa y el puerto correctos
- Navega hasta el ícono de Bibliotecas en la barra izquierda del Arduino IDE.
- Busca “keypad”, luego encuentra la biblioteca keypad de Mark Stanley, Alexander Brevig
- Haz clic en el botón Instalar para instalar la biblioteca keypad.
- Copia el código anterior y ábrelo con el IDE de Arduino
- Haz clic en el botón Subir en el IDE de Arduino para subir el código al Arduino
- Presione 12345#
- Presione 5642B#
- Vea el resultado en el Monitor Serial y el estado del servomotor
COM6
The password is incorrect, try again
The password is correct, rotating Servo Motor to 90°
Rotating Servo Motor to 0°
Autoscroll
Clear output
9600 baud
Newline
Explicación del código
Las contraseñas autorizadas están predefinidas en el código de Arduino.
Una cadena se utiliza para almacenar la contraseña introducida por los usuarios, llamada input_password. En el teclado, dos teclas (* y #) se utilizan con fines especiales: borrar la contraseña y finalizar la introducción de la contraseña. Cuando se pulsa una tecla en el teclado:
- Si la tecla pulsada no es una de las dos teclas especiales, se añade al input_password
- Si la tecla pulsada es *, input_password se borra. Puedes usarla para empezar o reiniciar la introducción de la contraseña
- Si la tecla pulsada es #:
- La input_password se compara con las contraseñas predefinidas. Si coincide con alguna de las contraseñas predefinidas, gira el servomotor a 90°.
- Independientemente de si la contraseña es correcta o no, la input_password se borra para la siguiente entrada
Video Tutorial
Estamos considerando crear tutoriales en video. Si considera que los tutoriales en video son importantes, suscríbase a nuestro canal de YouTube para motivarnos a crear los videos.