Arduino - Ethernet
Esta guía te enseña cómo conectar el Arduino a Internet o a tu red local utilizando el módulo Ethernet W5500. A continuación se detallarán los siguientes detalles:
- Conectando Arduino al Módulo Ethernet W5500
- Programando Arduino para Solicitudes HTTP a través de Ethernet
- Configurando un Servidor Web Simple en Arduino usando Ethernet
Hardware Requerido
Or you can buy the following kits:
| 1 | × | DIYables STEM V3 Starter Kit (Arduino included) | |
| 1 | × | DIYables Sensor Kit (30 sensors/displays) | |
| 1 | × | DIYables Sensor Kit (18 sensors/displays) |
Divulgación: Algunos de los enlaces proporcionados en esta sección son enlaces de afiliado de Amazon. Podemos recibir una comisión por las compras realizadas a través de estos enlaces sin costo adicional para usted. Apreciamos su apoyo.
Acerca del módulo Ethernet W5500
El módulo Ethernet W5500 presenta dos tipos de conexiones:
- Interfaz RJ45: Utilice esto para conectar a un router o a un switch con un cable Ethernet.
- Interfaz SPI: Utilice esto para conectar a una placa Arduino. Tiene 10 pines:
- Pin NC: No conecte este pin.
- Pin INT: No conecte este pin.
- Pin RST: Este es el pin de reset, conéctelo al pin EN del Arduino.
- Pin GND: Conecte este pin al pin GND del Arduino.
- Pin 5V: No conecte este pin.
- Pin 3.3V: Conecte este pin al pin 3.3V del Arduino.
- Pin MISO: Conecte este pin al pin MISO SPI del Arduino.
- Pin MOSI: Conecte este pin al pin MOSI SPI del Arduino.
- Pin SCS: Conecte este pin al pin CS SPI del Arduino.
- Pin SCLK: Conecte este pin al pin SCK SPI del Arduino.
image source: diyables.io
Diagrama de cableado entre Arduino y el módulo Ethernet W5500
This image is created using Fritzing. Click to enlarge image
image source: diyables.io
Código de Arduino para el módulo Ethernet - Realizar una solicitud HTTP a través de Ethernet
Este código actúa como un cliente web al enviar solicitudes HTTP al servidor web ubicado en http://example.com/.
/*
* Este código de Arduino fue desarrollado por es.newbiely.com
* Este código de Arduino se proporciona al público sin ninguna restricción.
* Para tutoriales completos y diagramas de cableado, visite:
* https://es.newbiely.com/tutorials/arduino/arduino-ethernet
*/
#include <SPI.h>
#include <Ethernet.h>
// replace the MAC address below by the MAC address printed on a sticker on the Arduino Shield 2
byte mac[] = { 0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED };
EthernetClient client;
int HTTP_PORT = 80;
String HTTP_METHOD = "GET"; // or POST
char HOST_NAME[] = "example.com";
String PATH_NAME = "/";
void setup() {
Serial.begin(9600);
delay(1000);
Serial.println("Arduino - Ethernet Tutorial");
// initialize the Ethernet shield using DHCP:
if (Ethernet.begin(mac) == 0) {
Serial.println("Failed to obtaining an IP address");
// check for Ethernet hardware present
if (Ethernet.hardwareStatus() == EthernetNoHardware)
Serial.println("Ethernet shield was not found");
// check for Ethernet cable
if (Ethernet.linkStatus() == LinkOFF)
Serial.println("Ethernet cable is not connected.");
while (true)
;
}
// connect to web server on port 80:
if (client.connect(HOST_NAME, HTTP_PORT)) {
// if connected:
Serial.println("Connected to server");
// make a HTTP request:
// send HTTP header
client.println(HTTP_METHOD + " " + PATH_NAME + " HTTP/1.1");
client.println("Host: " + String(HOST_NAME));
client.println("Connection: close");
client.println(); // end HTTP header
while (client.connected()) {
if (client.available()) {
// read an incoming byte from the server and print it to serial monitor:
char c = client.read();
Serial.print(c);
}
}
// the server's disconnected, stop the client:
client.stop();
Serial.println();
Serial.println("disconnected");
} else { // if not connected:
Serial.println("connection failed");
}
}
void loop() {
}
Pasos R\u00e1pidos
- Si eres nuevo en Arduino, empieza configurando el entorno en el IDE de Arduino siguiendo la guía aquí.
- Conecta el módulo Ethernet al Arduino según el diagrama de cableado proporcionado.
- Conecta el Arduino a tu computadora usando un cable USB.
- Conecta el módulo Ethernet a tu router o switch usando un cable Ethernet.
- Inicia el IDE de Arduino en tu computadora.
- Selecciona la placa de Arduino adecuada, como la Arduino Dev Module, y elige el puerto COM.
- Haz clic en el icono Bibliotecas en la barra izquierda del IDE de Arduino.
- Busca “Ethernet”, luego encuentra la biblioteca Ethernet de Various.
- Haz clic en el botón Instalar para instalar la biblioteca Ethernet.
- Abre el Monitor Serial en el IDE de Arduino.
- Copia el código proporcionado y pégalo en el IDE de Arduino.
- Haz clic en el botón Subir en el IDE de Arduino para subir el código al ESP25.
- Para ver la salida, consulta el Monitor Serial, que debería mostrar el resultado tal como se muestra.
COM6
Arduino - Ethernet Tutorial
Connected to server
HTTP/1.1 200 OK
Accept-Ranges: bytes
Age: 208425
Cache-Control: max-age=604800
Content-Type: text/html; charset=UTF-8
Date: Fri, 12 Jul 2024 07:08:42 GMT
Etag: "3147526947"
Expires: Fri, 19 Jul 2024 07:08:42 GMT
Last-Modified: Thu, 17 Oct 2019 07:18:26 GMT
Server: ECAcc (lac/55B8)
Vary: Accept-Encoding
X-Cache: HIT
Content-Length: 1256
Connection: close
<!doctype html>
<html>
<head>
<title>Example Domain</title>
<meta charset="utf-8" />
<meta http-equiv="Content-type" content="text/html; charset=utf-8" />
<meta name="viewport" content="width=device-width, initial-scale=1" />
</head>
<body>
<div>
<h1>Example Domain</h1>
<p>This domain is for use in illustrative examples in documents. You may use this
domain in literature without prior coordination or asking for permission.</p>
<p><a href="https://www.iana.org/domains/example">More information...</a></p>
</div>
</body>
</html>
disconnected
Autoscroll
Clear output
9600 baud
Newline
※ Nota:
Si otro dispositivo en la misma red tiene la misma dirección MAC, podría no funcionar.
Código de Arduino para el Módulo Ethernet - Servidor Web
El código que se muestra a continuación convierte al Arduino en un servidor web. Este servidor envía una página web simple a los navegadores web.
/*
* Este código de Arduino fue desarrollado por es.newbiely.com
* Este código de Arduino se proporciona al público sin ninguna restricción.
* Para tutoriales completos y diagramas de cableado, visite:
* https://es.newbiely.com/tutorials/arduino/arduino-ethernet
*/
#include <SPI.h>
#include <Ethernet.h>
// replace the MAC address below by the MAC address printed on a sticker on the Arduino Shield 2
byte mac[] = { 0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED };
EthernetServer server(80);
void setup() {
Serial.begin(9600);
delay(1000);
Serial.println("Arduino - Ethernet Tutorial");
// initialize the Ethernet shield using DHCP:
if (Ethernet.begin(mac) == 0) {
Serial.println("Failed to obtaining an IP address");
// check for Ethernet hardware present
if (Ethernet.hardwareStatus() == EthernetNoHardware)
Serial.println("Ethernet shield was not found");
// check for Ethernet cable
if (Ethernet.linkStatus() == LinkOFF)
Serial.println("Ethernet cable is not connected.");
while (true)
;
}
server.begin();
Serial.print("Arduino - Web Server IP Address: ");
Serial.println(Ethernet.localIP());
}
void loop() {
// listen for incoming clients
EthernetClient client = server.available();
if (client) {
Serial.println("new client");
// an HTTP request ends with a blank line
bool currentLineIsBlank = true;
while (client.connected()) {
if (client.available()) {
char c = client.read();
Serial.write(c);
// if you've gotten to the end of the line (received a newline
// character) and the line is blank, the HTTP request has ended,
// so you can send a reply
if (c == '\n' && currentLineIsBlank) {
// send a standard HTTP response header
client.println("HTTP/1.1 200 OK");
client.println("Content-Type: text/html");
client.println("Connection: close"); // the connection will be closed after completion of the response
client.println();
client.println("<!DOCTYPE HTML>");
client.println("<html>");
client.println("<body>");
client.println("<h1>Arduino - Web Server with Ethernet</h1>");
client.println("</body>");
client.println("</html>");
break;
}
if (c == '\n') {
// you're starting a new line
currentLineIsBlank = true;
} else if (c != '\r') {
// you've gotten a character on the current line
currentLineIsBlank = false;
}
}
}
// give the web browser time to receive the data
delay(1);
// close the connection:
client.stop();
Serial.println("client disconnected");
}
}
Pasos R\u00e1pidos
- Copie el código anterior y péguelo en el IDE de Arduino
- Haga clic en el botón Subir en el IDE de Arduino para cargar el código en Arduino
- Vea el resultado en el Monitor Serial; aparece como se muestra a continuación:
COM6
Arduino - Ethernet Tutorial
Arduino - Web Server IP Address: 192.168.0.2
Autoscroll
Clear output
9600 baud
Newline
- Copie la dirección IP que aparece arriba y péguela en la barra de direcciones de su navegador. Verá una página web simple que muestra el Arduino.
