ESP32 - Registrar datos con marca de tiempo en la tarjeta SD
En esta guía, exploraremos el proceso de registrar datos con marcas de tiempo en una tarjeta microSD utilizando ESP32. Específicamente, cubriremos los siguientes temas:
- Registro de datos con marcas de tiempo en un único archivo en una tarjeta microSD utilizando ESP32.
- Registro de datos con marcas de tiempo en múltiples archivos en una tarjeta microSD, con un archivo dedicado a cada día.
La información de tiempo se obtiene de un módulo RTC y luego se registra en la tarjeta microSD junto con los datos recopilados.
Los datos registrados en la tarjeta microSD pueden abarcar una variedad de información, como:
- Lecturas de datos de cualquier sensor.
- Un registro de acceso a una cerradura.
Para simplificar, este tutorial demostrará el proceso leyendo valores de dos pines analógicos, que servirán como un conjunto de datos de ejemplo. El código proporcionado puede adaptarse fácilmente para acomodar diferentes tipos de datos según sea necesario.
Hardware Requerido
Or you can buy the following kits:
| 1 | × | DIYables ESP32 Starter Kit (ESP32 included) | |
| 1 | × | DIYables Sensor Kit (30 sensors/displays) | |
| 1 | × | DIYables Sensor Kit (18 sensors/displays) |
Divulgación: Algunos de los enlaces proporcionados en esta sección son enlaces de afiliado de Amazon. Podemos recibir una comisión por las compras realizadas a través de estos enlaces sin costo adicional para usted. Apreciamos su apoyo.
Acerca del Módulo de Tarjeta microSD y del Módulo RTC
¿No estás familiarizado con el módulo de tarjeta microSD y el módulo RTC, incluyendo sus pines, su funcionalidad y su programación? Explora tutoriales completos sobre estos temas a continuación:
- ESP32 - Micro SD Card tutorial.
- ESP32 - Write Variable to SD Card tutorial.
- ESP32 - RTC module tutorial.
Diagrama de Cableado
This image is created using Fritzing. Click to enlarge image
Si no sabe c\u00f3mo alimentar ESP32 y otros componentes, encuentre instrucciones en el siguiente tutorial: C\u00f3mo alimentar ESP32.
※ Nota:
Si usas un escudo Ethernet o cualquier escudo que tenga un soporte para una tarjeta microSD, no necesitas usar el módulo de la tarjeta microSD. Solo necesitas insertar la tarjeta microSD en el soporte para microSD del escudo.
ESP32 - Registro de datos con marca de tiempo en la tarjeta microSD
/*
* Este código de ESP32 fue desarrollado por es.newbiely.com
* Este código de ESP32 se proporciona al público sin ninguna restricción.
* Para tutoriales completos y diagramas de cableado, visite:
* https://es.newbiely.com/tutorials/esp32/esp32-log-data-with-timestamp-to-sd-card
*/
#include <SD.h>
#include <RTClib.h>
#define PIN_SPI_CS 5 // The ESP32 pin GPIO5
#define FILE_NAME "/log.txt"
RTC_DS3231 rtc;
File myFile;
void setup() {
Serial.begin(9600);
// set the ADC attenuation to 11 dB (up to ~3.3V input)
analogSetAttenuation(ADC_11db);
// SETUP RTC MODULE
if (!rtc.begin()) {
while (1) {
Serial.println(F("RTC module is NOT found"));
delay(1000);
}
}
if (!SD.begin(PIN_SPI_CS)) {
while (1) {
Serial.println(F("SD CARD FAILED, OR NOT PRESENT!"));
delay(1000);
}
}
Serial.println(F("SD CARD INITIALIZED."));
Serial.println(F("--------------------"));
}
void loop() {
// open file for writing
myFile = SD.open(FILE_NAME, FILE_WRITE);
if (myFile) {
Serial.println(F("Writing log to SD Card"));
// write timestamp
DateTime now = rtc.now();
myFile.print(now.year(), DEC);
myFile.print('-');
myFile.print(now.month(), DEC);
myFile.print('-');
myFile.print(now.day(), DEC);
myFile.print(' ');
myFile.print(now.hour(), DEC);
myFile.print(':');
myFile.print(now.minute(), DEC);
myFile.print(':');
myFile.print(now.second(), DEC);
myFile.print(" "); // delimiter between timestamp and data
// read data
int analog_1 = analogRead(A0);
int analog_2 = analogRead(A1);
// write data
myFile.print("analog_1 = ");
myFile.print(analog_1);
myFile.print(", "); // delimiter between data
myFile.print("analog_2 = ");
myFile.print(analog_2);
myFile.write("\n"); // new line
myFile.close();
} else {
Serial.print(F("SD Card: Issue encountered while attempting to open the file "));
Serial.println(FILE_NAME);
}
delay(2000); // delay 2 seconds
}
Pasos R\u00e1pidos
- Si es la primera vez que usas ESP32, consulta cómo configurar el entorno para ESP32 en Arduino IDE.
- Realiza el cableado como en la imagen anterior.
- Conecta la placa ESP32 a tu PC mediante un cable micro USB.
- Abre el IDE de Arduino en tu PC.
- Selecciona la placa ESP32 adecuada (p. ej. ESP32 Dev Module) y el puerto COM.
- Asegúrate de que la tarjeta microSD esté formateada en FAT16 o FAT32 (búscalo en Google).
- Copia el código anterior y ábrelo con Arduino IDE.
- Haz clic en el botón Subir en Arduino IDE para subir el código al ESP32.
- Consulta el resultado en el Monitor Serial.
COM6
SD CARD INITIALIZED.
--------------------
Writing log to SD Card
Writing log to SD Card
Writing log to SD Card
Writing log to SD Card
Writing log to SD Card
Writing log to SD Card
Writing log to SD Card
Autoscroll
Clear output
9600 baud
Newline
- Retira la tarjeta microSD del módulo de tarjeta microSD
- Inserta la tarjeta microSD en un lector de tarjetas SD USB
- Conecta el lector de tarjetas SD USB al PC
- Abre el archivo log.txt en tu PC; se muestra a continuación
Si no tienes un lector USB de tarjetas SD, puedes revisar el contenido del archivo de registro ejecutando el código ESP32 que se muestra a continuación.
/*
* Este código de ESP32 fue desarrollado por es.newbiely.com
* Este código de ESP32 se proporciona al público sin ninguna restricción.
* Para tutoriales completos y diagramas de cableado, visite:
* https://es.newbiely.com/tutorials/esp32/esp32-log-data-with-timestamp-to-sd-card
*/
#include <SD.h>
#define PIN_SPI_CS 5 // The ESP32 pin GPIO5
#define FILE_NAME "/log.txt"
File myFile;
void setup() {
Serial.begin(9600);
if (!SD.begin(PIN_SPI_CS)) {
while (1) {
Serial.println(F("SD CARD FAILED, OR NOT PRESENT!"));
delay(1000);
}
}
Serial.println(F("SD CARD INITIALIZED."));
// open file for reading
myFile = SD.open(FILE_NAME, FILE_READ);
if (myFile) {
while (myFile.available()) {
char ch = myFile.read(); // read characters one by one from Micro SD Card
Serial.print(ch); // print the character to Serial Monitor
}
myFile.close();
} else {
Serial.print(F("SD Card: Issue encountered while attempting to open the file "));
Serial.println(FILE_NAME);
}
}
void loop() {
}
ESP32 - Registrar datos en múltiples archivos
Guardar el registro en un solo archivo resulta en un tamaño de archivo cada vez mayor con el tiempo y dificulta su revisión. El código siguiente escribirá el archivo de registro en múltiples archivos:
- Un archivo por día
- El nombre del archivo es la información de la fecha YYYYMMDD.txt
/*
* Este código de ESP32 fue desarrollado por es.newbiely.com
* Este código de ESP32 se proporciona al público sin ninguna restricción.
* Para tutoriales completos y diagramas de cableado, visite:
* https://es.newbiely.com/tutorials/esp32/esp32-log-data-with-timestamp-to-sd-card
*/
#include <SD.h>
#include <RTClib.h>
#define PIN_SPI_CS 5 // The ESP32 pin GPIO5
RTC_DS3231 rtc;
File myFile;
char filename[] = "/yyyymmdd.txt"; // filename (without extension) should not exceed 8 chars
void setup() {
Serial.begin(9600);
// set the ADC attenuation to 11 dB (up to ~3.3V input)
analogSetAttenuation(ADC_11db);
// SETUP RTC MODULE
if (!rtc.begin()) {
while (1) {
Serial.println(F("RTC module is NOT found"));
delay(1000);
}
}
if (!SD.begin(PIN_SPI_CS)) {
while (1) {
Serial.println(F("SD CARD FAILED, OR NOT PRESENT!"));
delay(1000);
}
}
Serial.println(F("SD CARD INITIALIZED."));
Serial.println(F("--------------------"));
}
void loop() {
DateTime now = rtc.now();
int year = now.year();
int month = now.month();
int day = now.day();
// update filename
filename[1] = (year / 1000) + '0';
filename[2] = ((year % 1000) / 100) + '0';
filename[3] = ((year % 100) / 10) + '0';
filename[4] = (year % 10) + '0';
filename[5] = (month / 10) + '0';
filename[6] = (month % 10) + '0';
filename[7] = (day / 10) + '0';
filename[8] = (day % 10) + '0';
// open file for writing
myFile = SD.open(filename, FILE_WRITE);
if (myFile) {
Serial.println(F("Writing log to SD Card"));
// write timestamp
myFile.print(now.year(), DEC);
myFile.print('-');
myFile.print(now.month(), DEC);
myFile.print('-');
myFile.print(now.day(), DEC);
myFile.print(' ');
myFile.print(now.hour(), DEC);
myFile.print(':');
myFile.print(now.minute(), DEC);
myFile.print(':');
myFile.print(now.second(), DEC);
myFile.print(" "); // delimiter between timestamp and data
// read data
int analog_1 = analogRead(A0);
int analog_2 = analogRead(A1);
// write data
myFile.print("analog_1 = ");
myFile.print(analog_1);
myFile.print(", "); // delimiter between data
myFile.print("analog_2 = ");
myFile.print(analog_2);
myFile.write("\n"); // new line
myFile.close();
} else {
Serial.print(F("SD Card: Issue encountered while attempting to open the file "));
Serial.println(filename);
}
delay(2000); // delay 2 seconds
}
Después de una larga carrera, si tú:
- Desconecte la tarjeta microSD del módulo microSD
- Inserte la tarjeta microSD en un lector de tarjetas SD USB
- Conecte el lector de tarjetas SD USB al PC
- Verá los archivos como se muestran a continuación:
Video Tutorial
Estamos considerando crear tutoriales en video. Si considera que los tutoriales en video son importantes, suscríbase a nuestro canal de YouTube para motivarnos a crear los videos.