ESP32 - Sistema de Cerradura de Puerta con Contraseña
Este tutorial explica cómo usar ESP32, un teclado numérico y una cerradura electromagnética para crear un sistema de cierre de puertas. A los usuarios se les pedirá la contraseña a través del teclado numérico. Si la contraseña es válida, el ESP32 controla la cerradura electromagnética para abrir la puerta. Los tutoriales también pueden incluir opcionalmente una pantalla LCD para mayor comodidad. El código del ESP32 también admite múltiples contraseñas.
Hardware Requerido
Or you can buy the following kits:
| 1 | × | DIYables ESP32 Starter Kit (ESP32 included) | |
| 1 | × | DIYables Sensor Kit (30 sensors/displays) | |
| 1 | × | DIYables Sensor Kit (18 sensors/displays) |
Divulgación: Algunos de los enlaces proporcionados en esta sección son enlaces de afiliado de Amazon. Podemos recibir una comisión por las compras realizadas a través de estos enlaces sin costo adicional para usted. Apreciamos su apoyo.
Acerca de Teclado numérico y Cerradura electromagnética y LCD
Tenemos tutoriales específicos sobre kypad, la cerradura electromagnética y la pantalla LCD. Cada tutorial contiene información detallada e instrucciones paso a paso sobre el pinout de hardware, el principio de funcionamiento, la conexión de cableado al ESP32 y código para ESP32... Aprende más sobre ellos en los siguientes enlaces:
Cómo comprobar la contraseña
- Una tecla especial * se usa para restablecer la contraseña.
- Una tecla especial # se utiliza para terminar la entrada de la contraseña.
- Cada tecla introducida, excepto * y #, se añade a una cadena.
- Cuando se presiona la tecla #, la entrada de la contraseña está completa. El ESP32 compara la cadena introducida con contraseñas predefinidas.
- Si la contraseña introducida es válida, se abre la puerta.
Diagrama de Cableado
This image is created using Fritzing. Click to enlarge image
Si no sabe c\u00f3mo alimentar ESP32 y otros componentes, encuentre instrucciones en el siguiente tutorial: C\u00f3mo alimentar ESP32.
Código ESP32 - sistema de cerradura para puertas con contraseña usando teclado numérico, cerradura electromagnética
/*
* Este código de ESP32 fue desarrollado por es.newbiely.com
* Este código de ESP32 se proporciona al público sin ninguna restricción.
* Para tutoriales completos y diagramas de cableado, visite:
* https://es.newbiely.com/tutorials/esp32/esp32-door-lock-system-using-password
*/
#include <Keypad.h>
#define RELAY_PIN 19 // ESP32 pin GPIO19 connected to the relay
#define ROW_NUM 4 // keypad four rows
#define COLUMN_NUM 3 // keypad three columns
char keys[ROW_NUM][COLUMN_NUM] = {
{'1', '2', '3'},
{'4', '5', '6'},
{'7', '8', '9'},
{'*', '0', '#'}
};
byte pin_rows[ROW_NUM] = {12, 14, 27, 26}; // ESP32 pin: GPIO12, GPIO14, GPIO27, GPIO26 connected to the row pins
byte pin_column[COLUMN_NUM] = {25, 33, 32}; // ESP32 pin: GPIO25, GPIO33, GPIO32 connected to the column pins
Keypad keypad = Keypad( makeKeymap(keys), pin_rows, pin_column, ROW_NUM, COLUMN_NUM );
const String password_1 = "1234"; // change your password here
const String password_2 = "4444"; // change your password here
const String password_3 = "55555"; // change your password here
String input_password;
void setup() {
Serial.begin(9600);
input_password.reserve(32); // maximum input characters is 32
pinMode(RELAY_PIN, OUTPUT);
digitalWrite(RELAY_PIN, HIGH); // lock the door
}
void loop() {
char key = keypad.getKey();
if (key) {
Serial.println(key);
if (key == '*') {
input_password = ""; // reset the input password
} else if (key == '#') {
if (input_password == password_1 || input_password == password_2 || input_password == password_3) {
Serial.println("Valid Password => unlock the door");
digitalWrite(RELAY_PIN, LOW); // unlock the door for 20 seconds
delay(20000);
digitalWrite(RELAY_PIN, HIGH); // lock the door
} else {
Serial.println("Invalid Password => Try again");
}
input_password = ""; // reset the input password
} else {
input_password += key; // append new character to input password string
}
}
}
Pasos R\u00e1pidos
- Si es la primera vez que usas ESP32, consulta cómo configurar el entorno para ESP32 en Arduino IDE.
- Realiza el cableado tal como se muestra en la imagen anterior.
- Conecta la placa ESP32 a tu PC mediante un cable micro USB.
- Abre Arduino IDE en tu PC.
- Selecciona la placa ESP32 correcta (p. ej. ESP32 Dev Module) y el puerto COM.
- Haz clic en el icono Libraries en la barra izquierda del Arduino IDE.
- Escribe “keypad” en la caja de búsqueda, luego busca la biblioteca keypad de Mark Stanley, Alexander Brevig
- Haz clic en el botón Instalar para instalar la biblioteca keypad.
- Copia el código anterior y pégalo en el Arduino IDE.
- Compila y sube el código a la placa ESP32 haciendo clic en el botón Subir en el Arduino IDE.
- Para simular la cerradura electromagnética instalada en la puerta, coloca el electroimán cerca de la placa de armadura.
- Presiona las teclas 1111 y presiona #.
- Comprueba la fuerza de atracción entre el electroimán y la placa de armadura.
- Presiona las teclas 1234 y presiona #.
- Comprueba la fuerza de atracción entre el electroimán y la placa de armadura.
- Ver el resultado en el Monitor Serie.
COM6
Invalid Password => Try again
Valid Password => unlock the door
Autoscroll
Clear output
9600 baud
Newline
Código ESP32 - Sistema de cerradura de puerta con contraseña usando teclado numérico, cerradura electromagnética y LCD
El siguiente código añade LCD I2C para mostrar el estado de acceso. Para el cableado con LCD, puedes ver en este tutorial Esp32 - LCD I2C tutorial
/*
* Este código de ESP32 fue desarrollado por es.newbiely.com
* Este código de ESP32 se proporciona al público sin ninguna restricción.
* Para tutoriales completos y diagramas de cableado, visite:
* https://es.newbiely.com/tutorials/esp32/esp32-door-lock-system-using-password
*/
#include <LiquidCrystal_I2C.h>
#include <Keypad.h>
#define RELAY_PIN 19 // ESP32 pin GPIO19 connected to the relay
#define ROW_NUM 4 // keypad four rows
#define COLUMN_NUM 3 // keypad three columns
char keys[ROW_NUM][COLUMN_NUM] = {
{'1', '2', '3'},
{'4', '5', '6'},
{'7', '8', '9'},
{'*', '0', '#'}
};
byte pin_rows[ROW_NUM] = {12, 14, 27, 26}; // ESP32 pin: GPIO12, GPIO14, GPIO27, GPIO26 connected to the row pins
byte pin_column[COLUMN_NUM] = {25, 33, 32}; // ESP32 pin: GPIO25, GPIO33, GPIO32 connected to the column pins
Keypad keypad = Keypad( makeKeymap(keys), pin_rows, pin_column, ROW_NUM, COLUMN_NUM );
const String password_1 = "1234"; // change your password here
const String password_2 = "4444"; // change your password here
const String password_3 = "55555"; // change your password here
String input_password;
LiquidCrystal_I2C lcd(0x27, 16, 2); // I2C address 0x27 (from DIYables LCD), 16 column and 2 rows
void setup() {
Serial.begin(9600);
input_password.reserve(32); // maximum input characters is 32
pinMode(RELAY_PIN, OUTPUT);
digitalWrite(RELAY_PIN, HIGH);
lcd.init(); // initialize the lcd
lcd.backlight();
}
void loop() {
char key = keypad.getKey();
if (key) {
Serial.println(key);
if (key == '*') {
input_password = ""; // reset the input password
lcd.clear();
} else if (key == '#') {
lcd.clear();
if (input_password == password_1 || input_password == password_2 || input_password == password_3) {
Serial.println("Valid Password => unlock the door");
lcd.setCursor(0, 0);
lcd.print("CORRECT!");
lcd.setCursor(0, 1);
lcd.print("DOOR UNLOCKED!");
digitalWrite(RELAY_PIN, LOW); // unlock the door for 20 seconds
delay(20000);
digitalWrite(RELAY_PIN, HIGH); // lock the door
} else {
Serial.println("Invalid Password => Try again");
lcd.setCursor(0, 0);
lcd.print("INCORRECT!");
lcd.setCursor(0, 1);
lcd.print("ACCESS DENIED!");
}
input_password = ""; // reset the input password
} else {
if (input_password.length() == 0) {
lcd.clear();
}
input_password += key; // append new character to input password string
lcd.setCursor(input_password.length(), 0); // move cursor to new position
lcd.print('*'); // print * key as hiden character
}
}
}
※ Nota:
La dirección I2C de la LCD puede variar entre fabricantes. En el código, usamos la dirección 0x27 que especifica el fabricante DIYables.
Video Tutorial
Estamos considerando crear tutoriales en video. Si considera que los tutoriales en video son importantes, suscríbase a nuestro canal de YouTube para motivarnos a crear los videos.