Arduino Nano - Leer la configuración desde la tarjeta SD
Este tutorial te enseña cómo usar un archivo de configuración en una tarjeta microSD. Específicamente, vamos a ver:
- Cómo crear un archivo config.txt en una tarjeta microSD, que contenga pares clave-valor
- Cómo leer la configuración desde la tarjeta microSD y guardarla en una variable int
- Cómo leer la configuración desde la tarjeta microSD y guardarla en una variable float
- Cómo leer la configuración desde la tarjeta microSD y guardarla en una variable String
Hardware Requerido
Or you can buy the following kits:
| 1 | × | DIYables Sensor Kit (18 sensors/displays) |
Divulgación: Algunos de los enlaces proporcionados en esta sección son enlaces de afiliado de Amazon. Podemos recibir una comisión por las compras realizadas a través de estos enlaces sin costo adicional para usted. Apreciamos su apoyo.
Acerca del módulo de la tarjeta microSD
Si no estás familiarizado con el módulo de la tarjeta Micro SD, incluida su distribución de pines, cómo funciona y cómo programarlo, consulta el tutorial Arduino Nano - Tarjeta Micro SD.
Cómo funciona
Cada par clave-valor se almacena en la tarjeta microSD en su propia línea. La clave y el valor están separados por un signo =. Un carácter de salto de línea separa cada par clave-valor de los demás.
El código para Arduino Nano buscará la clave y localizará el valor asociado, almacenándolo en una variable. La variable puede ser de tipo int, float o String.
Diagrama de Cableado
- Puedes usar cables jumper macho a hembra para conectar el módulo de tarjeta micro SD al Arduino Nano
This image is created using Fritzing. Click to enlarge image
- O también puedes conectar el módulo microSD a la placa de pruebas y luego usar cables de puente macho a macho.
This image is created using Fritzing. Click to enlarge image
Ver La mejor forma de alimentar Arduino Nano y otros componentes.
Cómo leer la configuración en variables
- Crea un archivo config.txt en tu PC usando Notepad o Notepad++.
- Copia los siguientes pares clave-valor y pégalos en el config.txt:
myString_1=Hello
myString_2=ArduinoGetStarted.com
myInt_1=2
myInt_2=-105
myFloat_1=0.74
myFloat_2=-46.08
- Conecta la tarjeta micro SD al PC con un lector de tarjetas SD USB 3.0.
- Asegúrate de que la tarjeta micro SD esté formateada en FAT16 o FAT32 (puedes buscar instrucciones en línea).
- Coloca el archivo config.txt en la carpeta principal de la tarjeta micro SD.
- Desconecta la tarjeta micro SD del PC.
- Conecta la tarjeta micro SD al Arduino Nano utilizando el módulo de tarjeta micro SD, siguiendo el diagrama de cableado.
- Copia el código a continuación y ábrelo con el IDE de Arduino.
/*
* Este código de Arduino Nano fue desarrollado por es.newbiely.com
* Este código de Arduino Nano se proporciona al público sin ninguna restricción.
* Para tutoriales completos y diagramas de cableado, visite:
* https://es.newbiely.com/tutorials/arduino-nano/arduino-nano-read-config-from-sd-card
*/
#include <SD.h>
#define PIN_SPI_CS 4
#define FILE_NAME "config.txt"
#define KEY_MAX_LENGTH 30 // change it if key is longer
#define VALUE_MAX_LENGTH 30 // change it if value is longer
// variables
int myInt_1;
int myInt_2;
float myFloat_1;
float myFloat_2;
String myString_1;
String myString_2;
void setup() {
Serial.begin(9600);
if (!SD.begin(PIN_SPI_CS)) {
Serial.println(F("SD Card failed, or not present"));
while (1); // don't do anything more:
}
Serial.println(F("SD Card initialized."));
myInt_1 = SD_findInt(F("myInt_1"));
myInt_2 = SD_findInt(F("myInt_2"));
myFloat_1 = SD_findFloat(F("myFloat_1"));
myFloat_2 = SD_findFloat(F("myFloat_2"));
myString_1 = SD_findString(F("myString_1"));
myString_2 = SD_findString(F("myString_2"));
Serial.print(F("myInt_1 = "));
Serial.println(myInt_1);
Serial.print(F("myInt_2 = "));
Serial.println(myInt_2);
Serial.print(F("myFloat_1 = "));
Serial.println(myFloat_1);
Serial.print(F("myFloat_2 = "));
Serial.println(myFloat_2);
Serial.print(F("myString_1 = "));
Serial.println(myString_1);
Serial.print(F("myString_2 = "));
Serial.println(myString_2);
}
void loop() {
}
bool SD_available(const __FlashStringHelper * key) {
char value_string[VALUE_MAX_LENGTH];
int value_length = SD_findKey(key, value_string);
return value_length > 0;
}
int SD_findInt(const __FlashStringHelper * key) {
char value_string[VALUE_MAX_LENGTH];
int value_length = SD_findKey(key, value_string);
return HELPER_ascii2Int(value_string, value_length);
}
float SD_findFloat(const __FlashStringHelper * key) {
char value_string[VALUE_MAX_LENGTH];
int value_length = SD_findKey(key, value_string);
return HELPER_ascii2Float(value_string, value_length);
}
String SD_findString(const __FlashStringHelper * key) {
char value_string[VALUE_MAX_LENGTH];
int value_length = SD_findKey(key, value_string);
return HELPER_ascii2String(value_string, value_length);
}
int SD_findKey(const __FlashStringHelper * key, char * value) {
File configFile = SD.open(FILE_NAME);
if (!configFile) {
Serial.print(F("SD Card: error on opening file "));
Serial.println(FILE_NAME);
return;
}
char key_string[KEY_MAX_LENGTH];
char SD_buffer[KEY_MAX_LENGTH + VALUE_MAX_LENGTH + 1]; // 1 is = character
int key_length = 0;
int value_length = 0;
// Flash string to string
PGM_P keyPoiter;
keyPoiter = reinterpret_cast<PGM_P>(key);
byte ch;
do {
ch = pgm_read_byte(keyPoiter++);
if (ch != 0)
key_string[key_length++] = ch;
} while (ch != 0);
// check line by line
while (configFile.available()) {
int buffer_length = configFile.readBytesUntil('\n', SD_buffer, 100);
if (SD_buffer[buffer_length - 1] == '\r')
buffer_length--; // trim the \r
if (buffer_length > (key_length + 1)) { // 1 is = character
if (memcmp(SD_buffer, key_string, key_length) == 0) { // equal
if (SD_buffer[key_length] == '=') {
value_length = buffer_length - key_length - 1;
memcpy(value, SD_buffer + key_length + 1, value_length);
break;
}
}
}
}
configFile.close(); // close the file
return value_length;
}
int HELPER_ascii2Int(char *ascii, int length) {
int sign = 1;
int number = 0;
for (int i = 0; i < length; i++) {
char c = *(ascii + i);
if (i == 0 && c == '-')
sign = -1;
else {
if (c >= '0' && c <= '9')
number = number * 10 + (c - '0');
}
}
return number * sign;
}
float HELPER_ascii2Float(char *ascii, int length) {
int sign = 1;
int decimalPlace = 0;
float number = 0;
float decimal = 0;
for (int i = 0; i < length; i++) {
char c = *(ascii + i);
if (i == 0 && c == '-')
sign = -1;
else {
if (c == '.')
decimalPlace = 1;
else if (c >= '0' && c <= '9') {
if (!decimalPlace)
number = number * 10 + (c - '0');
else {
decimal += ((float)(c - '0') / pow(10.0, decimalPlace));
decimalPlace++;
}
}
}
}
return (number + decimal) * sign;
}
String HELPER_ascii2String(char *ascii, int length) {
String str;
str.reserve(length);
str = "";
for (int i = 0; i < length; i++) {
char c = *(ascii + i);
str += String(c);
}
return str;
}
- Haz clic en el botón Subir en el IDE de Arduino para compilar y cargar el código al Arduino Nano.
- Consulta el Monitor Serial para ver el resultado.
8
Serial.println("Hello World!");
Message (Enter to send message to 'Arduino Nano' on 'COM15')
New Line
9600 baud
SD Card initialized.
myInt_1 = 2
myInt_2 = -105
myFloat_1 = 0.74
myFloat_2 = -46.08
myString_1 = Hello
myString_2 = ArduinoGetStarted.com
- El Monitor Serial muestra valores de variables que son iguales a los almacenados en la tarjeta micro SD.
Ahora puedes modificar el código para incluir variables adicionales.
※ Nota:
El código no tiene en cuenta la secuencia de pares clave-valor. Buscará a través del archivo desde el principio hasta el final hasta que se encuentre la clave.
Video Tutorial
Estamos considerando crear tutoriales en video. Si considera que los tutoriales en video son importantes, suscríbase a nuestro canal de YouTube para motivarnos a crear los videos.