Arduino UNO R4 - Ethernet
Esta guía te muestra cómo conectar el Arduino UNO R4 a Internet o a tu red local utilizando el módulo Ethernet W5500. Abordaremos los siguientes detalles:
- Cómo conectar Arduino UNO R4 con el módulo Ethernet W5500
- Cómo programar Arduino UNO R4 para realizar solicitudes HTTP a través de Ethernet
- Cómo crear un servidor web básico en Arduino UNO R4 a través de Ethernet
Hardware Requerido
Or you can buy the following kits:
| 1 | × | DIYables STEM V4 IoT Starter Kit (Arduino included) | |
| 1 | × | DIYables Sensor Kit (30 sensors/displays) | |
| 1 | × | DIYables Sensor Kit (18 sensors/displays) |
Divulgación: Algunos de los enlaces proporcionados en esta sección son enlaces de afiliado de Amazon. Podemos recibir una comisión por las compras realizadas a través de estos enlaces sin costo adicional para usted. Apreciamos su apoyo.
Acerca del módulo Ethernet W5500
El módulo Ethernet W5500 ofrece dos interfaces:
- Interfaz Ethernet RJ45: Conéctese a un router o conmutador utilizando un cable Ethernet.
- Interfaz SPI: Conéctese a una placa Arduino UNO R4 utilizando esta interfaz. Incluye 10 pines:
- Pin NC: Deje este pin sin conectar.
- Pin INT: Deje este pin sin conectar.
- Pin RST: Este es el pin de reinicio. Conéctelo al pin EN de la placa Arduino UNO R4.
- Pin GND: Conecte este pin al pin GND de la placa Arduino UNO R4.
- Pin 5V: Conecte este pin al pin 5V de la placa Arduino UNO R4.
- Pin 3.3V: Deje este pin sin conectar.
- Pin MISO: Conecte este pin al pin SPI MISO de la placa Arduino UNO R4.
- Pin MOSI: Conecte este pin al pin SPI MOSI de la placa Arduino UNO R4.
- Pin SCS: Conecte este pin al pin SPI CS de la placa Arduino UNO R4.
- Pin SCLK: Conecte este pin al pin SPI SCK de la placa Arduino UNO R4.
image source: diyables.io
Diagrama de cableado entre Arduino UNO R4 y el módulo Ethernet W5500
This image is created using Fritzing. Click to enlarge image
Ver La mejor forma de alimentar Arduino Uno R4 y otros componentes.
Código de Arduino UNO R4 para el módulo Ethernet - Realizando una solicitud HTTP a través de Ethernet
Este código funciona como un cliente web. Envía solicitudes HTTP al servidor web en http://example.com/.
/*
* Este código de Arduino UNO R4 fue desarrollado por es.newbiely.com
* Este código de Arduino UNO R4 se proporciona al público sin ninguna restricción.
* Para tutoriales completos y diagramas de cableado, visite:
* https://es.newbiely.com/tutorials/arduino-uno-r4/arduino-uno-r4-ethernet-module
*/
#include <SPI.h>
#include <Ethernet.h>
// replace the MAC address below by the MAC address printed on a sticker on the Arduino Shield 2
byte mac[] = { 0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED };
EthernetClient client;
int HTTP_PORT = 80;
String HTTP_METHOD = "GET"; // or POST
char HOST_NAME[] = "example.com";
String PATH_NAME = "/";
void setup() {
Serial.begin(9600);
delay(1000);
Serial.println("Arduino Uno R4 - Ethernet Tutorial");
// initialize the Ethernet shield using DHCP:
if (Ethernet.begin(mac) == 0) {
Serial.println("Failed to obtaining an IP address");
// check for Ethernet hardware present
if (Ethernet.hardwareStatus() == EthernetNoHardware)
Serial.println("Ethernet shield was not found");
// check for Ethernet cable
if (Ethernet.linkStatus() == LinkOFF)
Serial.println("Ethernet cable is not connected.");
while (true)
;
}
// connect to web server on port 80:
if (client.connect(HOST_NAME, HTTP_PORT)) {
// if connected:
Serial.println("Connected to server");
// make a HTTP request:
// send HTTP header
client.println(HTTP_METHOD + " " + PATH_NAME + " HTTP/1.1");
client.println("Host: " + String(HOST_NAME));
client.println("Connection: close");
client.println(); // end HTTP header
while (client.connected()) {
if (client.available()) {
// read an incoming byte from the server and print it to serial monitor:
char c = client.read();
Serial.print(c);
}
}
// the server's disconnected, stop the client:
client.stop();
Serial.println();
Serial.println("disconnected");
} else { // if not connected:
Serial.println("connection failed");
}
}
void loop() {
}
Pasos R\u00e1pidos
Siga estas instrucciones paso a paso:
- Si es la primera vez que utilizas el Arduino Uno R4 WiFi/Minima, consulta el tutorial sobre configurar el entorno para Arduino Uno R4 WiFi/Minima en el IDE de Arduino.
- Conecta el módulo Ethernet a tu Arduino UNO R4 según el diagrama proporcionado.
- Conecta el módulo Ethernet a tu router o conmutador usando un cable Ethernet.
- Conecta la placa Arduino Uno R4 a tu computadora usando un cable USB.
- Abre el IDE de Arduino en tu computadora.
- Selecciona la placa Arduino Uno R4 adecuada (p. ej., Arduino Uno R4 Minima) y el puerto COM.
- Haz clic en el icono Bibliotecas en el lado izquierdo del IDE de Arduino.
- En la caja de búsqueda, escribe “Ethernet” y localiza la biblioteca Ethernet de Various.
- Presiona el botón Instalar para añadir la biblioteca Ethernet.
- Abre el Monitor Serial en el IDE de Arduino.
- Copia el código proporcionado y pégalo en el IDE de Arduino.
- Haz clic en el botón Subir en el IDE de Arduino para enviar el código al Arduino Uno R4.
- Para ver la salida, consulta el Monitor Serial donde se mostrarán los resultados como se indica.
COM6
Arduino UNO R4 - Ethernet Tutorial
Connected to server
HTTP/1.1 200 OK
Accept-Ranges: bytes
Age: 208425
Cache-Control: max-age=604800
Content-Type: text/html; charset=UTF-8
Date: Fri, 12 Jul 2024 07:08:42 GMT
Etag: "3147526947"
Expires: Fri, 19 Jul 2024 07:08:42 GMT
Last-Modified: Thu, 17 Oct 2019 07:18:26 GMT
Server: ECAcc (lac/55B8)
Vary: Accept-Encoding
X-Cache: HIT
Content-Length: 1256
Connection: close
<!doctype html>
<html>
<head>
<title>Example Domain</title>
<meta charset="utf-8" />
<meta http-equiv="Content-type" content="text/html; charset=utf-8" />
<meta name="viewport" content="width=device-width, initial-scale=1" />
</head>
<body>
<div>
<h1>Example Domain</h1>
<p>This domain is for use in illustrative examples in documents. You may use this
domain in literature without prior coordination or asking for permission.</p>
<p><a href="https://www.iana.org/domains/example">More information...</a></p>
</div>
</body>
</html>
disconnected
Autoscroll
Clear output
9600 baud
Newline
※ Nota:
Si otro dispositivo en la misma red comparte tu dirección MAC, podría haber problemas.
Código de Arduino UNO R4 para el módulo Ethernet - Servidor Web
El código a continuación convierte el Arduino UNO R4 en un servidor web. Este servidor envía una página web simple a los navegadores de Internet.
/*
* Este código de Arduino UNO R4 fue desarrollado por es.newbiely.com
* Este código de Arduino UNO R4 se proporciona al público sin ninguna restricción.
* Para tutoriales completos y diagramas de cableado, visite:
* https://es.newbiely.com/tutorials/arduino-uno-r4/arduino-uno-r4-ethernet-module
*/
#include <SPI.h>
#include <Ethernet.h>
// replace the MAC address below by the MAC address printed on a sticker on the Arduino Shield 2
byte mac[] = { 0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED };
EthernetServer server(80);
void setup() {
Serial.begin(9600);
delay(1000);
Serial.println("Arduino Uno R4 - Ethernet Tutorial");
// initialize the Ethernet shield using DHCP:
if (Ethernet.begin(mac) == 0) {
Serial.println("Failed to obtaining an IP address");
// check for Ethernet hardware present
if (Ethernet.hardwareStatus() == EthernetNoHardware)
Serial.println("Ethernet shield was not found");
// check for Ethernet cable
if (Ethernet.linkStatus() == LinkOFF)
Serial.println("Ethernet cable is not connected.");
while (true)
;
}
server.begin();
Serial.print("Arduino Uno R4 - Web Server IP Address: ");
Serial.println(Ethernet.localIP());
}
void loop() {
// listen for incoming clients
EthernetClient client = server.available();
if (client) {
Serial.println("new client");
// an HTTP request ends with a blank line
bool currentLineIsBlank = true;
while (client.connected()) {
if (client.available()) {
char c = client.read();
Serial.write(c);
// if you've gotten to the end of the line (received a newline
// character) and the line is blank, the HTTP request has ended,
// so you can send a reply
if (c == '\n' && currentLineIsBlank) {
// send a standard HTTP response header
client.println("HTTP/1.1 200 OK");
client.println("Content-Type: text/html");
client.println("Connection: close"); // the connection will be closed after completion of the response
client.println();
client.println("<!DOCTYPE HTML>");
client.println("<html>");
client.println("<body>");
client.println("<h1>Arduino Uno R4 - Web Server with Ethernet</h1>");
client.println("</body>");
client.println("</html>");
break;
}
if (c == '\n') {
// you're starting a new line
currentLineIsBlank = true;
} else if (c != '\r') {
// you've gotten a character on the current line
currentLineIsBlank = false;
}
}
}
// give the web browser time to receive the data
delay(1);
// close the connection:
client.stop();
Serial.println("client disconnected");
}
}
Pasos R\u00e1pidos
- Copia el código anterior y pégalo en el IDE de Arduino.
- Haz clic en el botón Subir en el IDE de Arduino para subir el código a Arduino Uno R4.
- Verifica el resultado en el Monitor Serial; se mostrará como sigue:
COM6
Arduino UNO R4 - Ethernet Tutorial
Arduino UNO R4 - Web Server IP Address: 192.168.0.2
Autoscroll
Clear output
9600 baud
Newline
- Copie la dirección IP indicada arriba y péguela en la barra de direcciones de su navegador. Verá una página web simple que es mostrada por el Arduino UNO R4.
