Arduino Nano ESP32 - Reproductor de MP3
En esta guía, descubriremos cómo crear un reproductor de MP3 utilizando un ESP32, un módulo reproductor de MP3, una tarjeta micro SD y un altavoz. Los archivos MP3, que pueden ser música o audio grabado, se guardan en la tarjeta micro SD. El Arduino Nano ESP32 se programará para enviar comandos que controlen el módulo reproductor de MP3 para decidir qué canción elegir de la tarjeta SD, convertirla en sonido y luego enviar ese sonido al altavoz. Abordaremos los siguientes aspectos:
- Cómo funciona un reproductor de MP3
- Conectar el altavoz y los módulos de reproductor de MP3 al Arduino Nano ESP32
- Programar el Arduino Nano ESP32 para reproducir una canción almacenada en la tarjeta microSD
- Agregar botones de reproducción, pausa, siguiente y anterior
Después, puedes llevar el código un paso más al incorporar un potenciómetro o un codificador rotatorio para ajustar el volumen.
Hardware Requerido
Or you can buy the following kits:
| 1 | × | DIYables Sensor Kit (30 sensors/displays) | |
| 1 | × | DIYables Sensor Kit (18 sensors/displays) |
Divulgación: Algunos de los enlaces proporcionados en esta sección son enlaces de afiliado de Amazon. Podemos recibir una comisión por las compras realizadas a través de estos enlaces sin costo adicional para usted. Apreciamos su apoyo.
Acerca del módulo reproductor MP3 serial y del altavoz
Esquema de pines del módulo reproductor MP3 en serie
Un módulo reproductor de MP3 serial tiene tres interfaces:
- La interfaz para Arduino Nano ESP32 incluye 4 pines:
- Pin RX: pin de datos, debe conectarse al pin TX del Arduino Nano ESP32
- Pin TX: pin de datos, debe conectarse al pin RX del Arduino Nano ESP32
- Pin VCC: pin de alimentación, debe conectarse a VCC (5V)
- Pin GND: pin de alimentación, debe conectarse a GND (0V)
- La interfaz para el altavoz es un conector hembra de salida AUX de 3,5 mm.
- La interfaz para la tarjeta microSD es una ranura para microSD en la parte trasera del módulo.
Pinout del altavoz
Un altavoz suele tener dos interfaces:
- Interfaz de señal de audio: es un conector macho de 3,5 mm auxiliar que se conecta al módulo reproductor de MP3
- Interfaz de alimentación: puede ser USB, un adaptador de alimentación de 5 V o cualquier otra interfaz de alimentación
Cómo funciona
Para empezar, asegúrese de tener lo siguiente:
- Reúne una colección de canciones o audios grabados que quieras reproducir y guárdalos en una tarjeta micro SD.
- Inserta la tarjeta micro SD en el módulo reproductor de MP3.
- Conecta el módulo reproductor de MP3 al Arduino Nano ESP32 y conecta el altavoz al módulo reproductor de MP3. Además, asegúrate de que el altavoz esté conectado a una fuente de alimentación.
Cada archivo MP3 en la tarjeta microSD recibe un identificador, empezando desde 0. Luego, puedes decirle al Arduino Nano ESP32 que haga varias cosas con el módulo reproductor de MP3, como:
- Reproducir: Comenzar a reproducir la canción seleccionada.
- Pausar: Pausar la canción.
- Reproducir siguiente: Ir a la siguiente canción.
- Reproducir anterior: Volver a la canción anterior.
- Cambiar el volumen: Ajustar cuán fuerte es la música.
Cuando el módulo reproductor de MP3 recibe un comando, lee el archivo MP3 desde la tarjeta microSD, lo convierte en una señal de audio y envía esa señal al altavoz utilizando una conexión auxiliar de 3,5 mm.
Diagrama de Cableado
This image is created using Fritzing. Click to enlarge image
Código de Arduino Nano ESP32 - Reproducir música
El código de abajo reproduce la primera canción almacenada en la tarjeta microSD.
/*
* Este código de Arduino Nano ESP32 fue desarrollado por es.newbiely.com
* Este código de Arduino Nano ESP32 se proporciona al público sin ninguna restricción.
* Para tutoriales completos y diagramas de cableado, visite:
* https://es.newbiely.com/tutorials/arduino-nano-esp32/arduino-nano-esp32-mp3-player
*/
#define CMD_PLAY_NEXT 0x01
#define CMD_PLAY_PREV 0x02
#define CMD_PLAY_W_INDEX 0x03
#define CMD_SET_VOLUME 0x06
#define CMD_SEL_DEV 0x09
#define CMD_PLAY_W_VOL 0x22
#define CMD_PLAY 0x0D
#define CMD_PAUSE 0x0E
#define CMD_SINGLE_CYCLE 0x19
#define DEV_TF 0x02
#define SINGLE_CYCLE_ON 0x00
#define SINGLE_CYCLE_OFF 0x01
#define RX1PIN D8 // Arduino Nano Pin connected to the TX of the Serial MP3 Player module
#define TX1PIN D7 // Arduino Nano Pin connected to the RX of the Serial MP3 Player module
void setup() {
Serial.begin(9600);
Serial1.begin(9600, SERIAL_8N1, RX1PIN, TX1PIN);
delay(500); // wait chip initialization is complete
mp3_command(CMD_SEL_DEV, DEV_TF); // select the TF card
delay(200); // wait for 200ms
mp3_command(CMD_PLAY, 0x0000); // Play mp3
//mp3_command(CMD_PAUSE, 0x0000); // Pause mp3
//mp3_command(CMD_PLAY_NEXT, 0x0000); // Play next mp3
//mp3_command(CMD_PLAY_PREV, 0x0000); // Play previous mp3
//mp3_command(CMD_SET_VOLUME, 30); // Change volume to 30
}
void loop() {
}
void mp3_command(int8_t command, int16_t dat) {
int8_t frame[8] = { 0 };
frame[0] = 0x7e; // starting byte
frame[1] = 0xff; // version
frame[2] = 0x06; // The number of bytes of the command without starting byte and ending byte
frame[3] = command; //
frame[4] = 0x00; // 0x00 = no feedback, 0x01 = feedback
frame[5] = (int8_t)(dat >> 8); // data high byte
frame[6] = (int8_t)(dat); // data low byte
frame[7] = 0xef; // ending byte
for (uint8_t i = 0; i < 8; i++) {
Serial1.write(frame[i]);
}
}
Pasos R\u00e1pidos
- Si es la primera vez que usas Arduino Nano ESP32, consulta cómo configurar el entorno para Arduino Nano ESP32 en Arduino IDE.
- Sigue las instrucciones en Cómo funciona
- Copia el código anterior y ábrelo con el IDE de Arduino
- Haz clic en el botón Subir en el IDE de Arduino para cargar el código al Arduino Nano ESP32
- Disfruta de la música
Código de Arduino Nano ESP32 - Reproducir música con botones de control
El código que se muestra a continuación es una mejora del código anterior. Añade cuatro botones para que puedas interactuar con el reproductor de MP3.
/*
* Este código de Arduino Nano ESP32 fue desarrollado por es.newbiely.com
* Este código de Arduino Nano ESP32 se proporciona al público sin ninguna restricción.
* Para tutoriales completos y diagramas de cableado, visite:
* https://es.newbiely.com/tutorials/arduino-nano-esp32/arduino-nano-esp32-mp3-player
*/
#include <ezButton.h>
#define CMD_PLAY_NEXT 0x01
#define CMD_PLAY_PREV 0x02
#define CMD_PLAY_W_INDEX 0x03
#define CMD_SET_VOLUME 0x06
#define CMD_SEL_DEV 0x09
#define CMD_PLAY_W_VOL 0x22
#define CMD_PLAY 0x0D
#define CMD_PAUSE 0x0E
#define CMD_SINGLE_CYCLE 0x19
#define DEV_TF 0x02
#define SINGLE_CYCLE_ON 0x00
#define SINGLE_CYCLE_OFF 0x01
#define RX1PIN D8 // Arduino Nano ESP32 Pin connected to the TX of the Serial MP3 Player module
#define TX1PIN D7 // Arduino Nano ESP32 Pin connected to the RX of the Serial MP3 Player module
ezButton button_play(D2); // create ezButton object for pin D2
ezButton button_pause(D3); // create ezButton object for pin D3
ezButton button_next(D4); // create ezButton object for pin D4
ezButton button_prev(D5); // create ezButton object for pin D5
void setup() {
Serial.begin(9600);
Serial1.begin(9600, SERIAL_8N1, RX1PIN, TX1PIN);;
delay(500); // wait chip initialization is complete
mp3_command(CMD_SEL_DEV, DEV_TF); // select the TF card
delay(200); // wait for 200ms
button_play.setDebounceTime(50); // set debounce time to 50 milliseconds
button_pause.setDebounceTime(50); // set debounce time to 50 milliseconds
button_next.setDebounceTime(50); // set debounce time to 50 milliseconds
button_prev.setDebounceTime(50); // set debounce time to 50 milliseconds
}
void loop() {
button_play.loop(); // MUST call the loop() function first
button_pause.loop(); // MUST call the loop() function first
button_next.loop(); // MUST call the loop() function first
button_prev.loop(); // MUST call the loop() function first
if (button_play.isPressed()) {
Serial.println("Play mp3");
mp3_command(CMD_PLAY, 0x0000);
}
if (button_pause.isPressed()) {
Serial.println("Pause mp3");
mp3_command(CMD_PAUSE, 0x0000);
}
if (button_next.isPressed()) {
Serial.println("Play next mp3");
mp3_command(CMD_PLAY_NEXT, 0x0000);
}
if (button_prev.isPressed()) {
Serial.println("Play previous mp3");
mp3_command(CMD_PLAY_PREV, 0x0000);
}
}
void mp3_command(int8_t command, int16_t dat) {
int8_t frame[8] = { 0 };
frame[0] = 0x7e; // starting byte
frame[1] = 0xff; // version
frame[2] = 0x06; // The number of bytes of the command without starting byte and ending byte
frame[3] = command; //
frame[4] = 0x00; // 0x00 = no feedback, 0x01 = feedback
frame[5] = (int8_t)(dat >> 8); // data high byte
frame[6] = (int8_t)(dat); // data low byte
frame[7] = 0xef; // ending byte
for (uint8_t i = 0; i < 8; i++) {
Serial1.write(frame[i]);
}
}
El diagrama de cableado para el código anterior:
This image is created using Fritzing. Click to enlarge image
Ahora puedes modificar los proyectos para agregar más funciones, por ejemplo:
- Añadir un potenciómetro para controlar el volumen, ver Potenciómetro de Arduino Nano ESP32 tutorial
- Añadir un controlador remoto IR, ver Controlador remoto IR de Arduino Nano ESP32 tutorial
- Añadir un lector y una tarjeta RFID para crear un reproductor MP3 RFID, ver RFID de Arduino Nano ESP32 tutorial
Video Tutorial
Estamos considerando crear tutoriales en video. Si considera que los tutoriales en video son importantes, suscríbase a nuestro canal de YouTube para motivarnos a crear los videos.